@echo off
chcp 65001 >nul
title Aetherion Chat starten
setlocal

set "SERVER=https://discord.netcorex.home64.de"
set "STOAT=%LOCALAPPDATA%\Stoat\stoat-desktop.exe"

echo.
echo   ============================================
echo      Aetherion Chat
echo   ============================================
echo.

if not exist "%STOAT%" (
  echo   Die Stoat-App ist auf diesem PC noch nicht installiert.
  echo.
  echo   Ich oeffne jetzt die Downloadseite. Bitte installieren
  echo   und danach diese Datei noch einmal doppelklicken.
  echo.
  pause
  start "" "https://stoat.chat/download"
  exit /b
)

echo   Verbinde mit: %SERVER%
echo.

rem  Eine Verknuepfung auf dem Desktop anlegen, damit man diese
rem  Datei kuenftig nicht mehr sucht.
set "LNK=%USERPROFILE%\Desktop\Aetherion Chat.lnk"
if not exist "%LNK%" (
  powershell -NoProfile -Command ^
    "$w=New-Object -ComObject WScript.Shell;" ^
    "$l=$w.CreateShortcut('%LNK%');" ^
    "$l.TargetPath='%STOAT%';" ^
    "$l.Arguments='--force-server=%SERVER%';" ^
    "$l.WorkingDirectory='%LOCALAPPDATA%\Stoat';" ^
    "$l.Description='Aetherion Chat';" ^
    "$l.Save()" >nul 2>&1
  if exist "%LNK%" echo   Auf dem Desktop liegt jetzt: "Aetherion Chat"
)

start "" "%STOAT%" --force-server=%SERVER%
echo   Fertig. Das Fenster kann geschlossen werden.
ping -n 5 127.0.0.1 >nul